admin管理员组文章数量:1627944
公司配网时常遇到Windows主机内外网切换,所以写了一个配网脚本,简单易用,提高效率。
运行环境:Windows 11 家庭中文版
首先在cmd中ipconfig查看以太网卡名称:(如果是WiFi连接的话查看的是无线网卡名称)
可见我的以太网卡名称为:以太网 2
,然后新建txt文件,将以下代码复制粘贴,在网络名称部分按照刚查询到的网卡名称进行修改,配网参数部分按照自己需求进行修改,注释已经写的很清晰了:
@echo off
rem 获取管理员权限
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
rem 网络名称,根据系统配置修改
set NAME="以太网 2"
rem 配网参数,按照自己需求修改
set ADDR-内网=192.168.107.18
set MASK-内网=255.255.255.0
set GATEWAY-内网=192.168.107.1
set DNS1-内网=192.168.116.53
set DNS2-内网=192.168.116.54
set ADDR-外网=10.10.11.122
set MASK-外网=255.255.255.0
set GATEWAY-外网=10.10.11.100
set DNS1-外网=8.8.8.8
set DNS2-外网=114.114.114.114
echo 当前可用操作有:
echo 1 设置为静态IP-内网
echo 2 设置为静态IP-外网
echo 3 设置为动态IP
echo 4 退出
echo 请选择后回车:
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 goto 3
if %operate%==4 goto 4
:1
echo 正在设置静态IP-内网,请稍等...
echo IP地址 = %ADDR-内网%
echo 掩码 = %MASK-内网%
echo 网关 = %GATEWAY-内网%
netsh interface ipv4 set address %NAME% static %ADDR-内网% %MASK-内网% %GATEWAY-内网%
echo 首选DNS = %DNS1-内网%
if "%DNS1-内网%"=="" (echo DNS1为空) else netsh interface ipv4 set dns %NAME% static %DNS1-内网%
echo 备用DNS = %DNS2-内网%
if "%DNS2-内网%"=="" (echo DNS2为空) else (netsh interface ipv4 add dns %NAME% %DNS2-内网%)
echo **********已设置为静态IP:%ADDR-内网%***********
pause
goto 4
:2
echo 正在设置静态IP-外网,请稍等...
echo IP地址 = %ADDR-外网%
echo 掩码 = %MASK-外网%
echo 网关 = %GATEWAY-外网%
netsh interface ipv4 set address %NAME% static %ADDR-外网% %MASK-外网% %GATEWAY-外网%
echo 首选DNS = %DNS1-外网%
if "%DNS1-外网%"=="" (echo DNS1为空) else netsh interface ipv4 set dns %NAME% static %DNS1-外网%
echo 备用DNS = %DNS2-外网%
if "%DNS2-外网%"=="" (echo DNS2为空) else (netsh interface ipv4 add dns %NAME% %DNS2-外网%)
echo **********已设置为静态IP:%ADDR-外网%***********
pause
goto 4
:3
echo 正在设置动态IP,请稍等...
echo 正在从DHCP自动获取IP地址...
netsh interface ip set address %NAME% dhcp
echo 正在从DHCP自动获取DNS地址...
netsh interface ip set dns %NAME% dhcp
echo **********已设置为动态IP地址***********
pause
goto 4
:4
exit
然后将文件另存为bat脚本文件,划重点!中文版系统一定要选择ANSI编码,这样执行时才不会出现乱码报错:
最后双击bat脚本执行就可以了:
版权声明:本文标题:Windows一键配网脚本 内容由热心网友自发贡献,该文观点仅代表作者本人, 转载请联系作者并注明出处:https://m.elefans.com/dongtai/1729003530a1182766.html, 本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌抄袭侵权/违法违规的内容,一经查实,本站将立刻删除。
发表评论