Mplus—随机截距交叉滞后模型（RI-CLPM）语法

admin管理员组

文章数量:1660203

目录

Basic RI-CLPM

语法1

语法2

Basic RI-CLPM

说到RI-CLPM，通常是指将观察分数分为个体间水平和个体内水平，即在显变量层面上进行分析。

The random intercept cross-lagged panel model (RI-CLPM) as proposed by Hamaker, Kuiper and Grasman (2015, Psychological Methods) is a model that decomposes each observed score into a between-person part and a within-person part (Hamaker, 2018).

如下图所示RI-CLPM，对两个变量（X、Y）进行了5次测量。以此为例，在Mplus中根据模型图写出相应语句即可。

语法1

TITLE: The basic RI-CLPM, 5 waves, 2 variables.

            ! 该文件的内容为RI-CLPM的语法，其中包括2个变量，进行了5次测量

DATA: FILE = RICLPM.dat; ! 数据来源

VARIABLE: NAMES = x1-x5 y1-y5; ! 变量名称

ANALYSIS: MODEL = NOCOV; ! Sets all default covariances to zero

                                                   ! 通过该语句将所有默认协方差设置为零

MODEL:

! Create between components (random intercepts)

! 个体间水平上，创建两个随机截距RIx和RIy

RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;

RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;

! Create within-person centered variables

! 个体内水平上，创建变量wx1-wx5、wy1-wy5

wx1 BY x1@1;

wx2 BY x2@1;

wx3 BY x3@1;

wx4 BY x4@1;

wx5 BY x5@1;

wy1 BY y1@1;

wy2 BY y2@1;

wy3 BY y3@1;

wy4 BY y4@1;

wy5 BY y5@1;

! Constrain measurement error variances to 0

! 将测量误差方差限制为0

x1-y5@0;

! Estimate lagged effects between within-person centered variables

! 估计个体内变量的自回归和交叉滞后效应

wx2 wy2 ON wx1 wy1;

wx3 wy3 ON wx2 wy2;

wx4 wy4 ON wx3 wy3;

wx5 wy5 ON wx4 wy4;

! Estimate covariance between random intercepts

! 估计随机截距之间的协方差（相关）

RIx WITH RIy;

! Estimate covariance between within-person components at first wave

! 估计第一个时间点个体内变量之间的协方差（相关）

wx1 WITH wy1;

! Estimate covariances between residuals of within-person components

! 估计其他时间点个体内变量残差之间的协方差（相关）

wx2 WITH wy2;

wx3 WITH wy3;

wx4 WITH wy4;

wx5 WITH wy5;

OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;

语法2

TITLE: The basic RI-CLPM, 5 waves, 2 variables.

DATA: FILE = RICLPM.dat;

VARIABLE: NAMES = x1-x5 y1-y5;

MODEL:

! Create between components (random intercepts)

RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;

RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;

! Create within-person centered variables

wx1 BY x1@1;

wx2 BY x2@1;

wx3 BY x3@1;

wx4 BY x4@1;

wx5 BY x5@1;

wy1 BY y1@1;

wy2 BY y2@1;

wy3 BY y3@1;

wy4 BY y4@1;

wy5 BY y5@1;

! Constrain measurement error variances to 0

x1-y5@0;

! Estimate lagged effects between within-person centered variables

wx2 wy2 ON wx1 wy1;

wx3 wy3 ON wx2 wy2;

wx4 wy4 ON wx3 wy3;

wx5 wy5 ON wx4 wy4;

! Estimate covariance between random intercepts

RIx WITH RIy;

! Estimate covariance between within-person components at first wave

wx1 WITH wy1;

! Estimate covariances between residuals of within-person components

wx2 WITH wy2;

wx3 WITH wy3;

wx4 WITH wy4;

wx5 WITH wy5;

! Fix the correlation between the individual factors and ! the other exogenous variables to zero (by default these would be estimated)

! 将个体间因素，也就是随机截距和其他外生变量之间的相关性固定为零

! Mplus默认情况下，会估计这些变量之间的相关

RIx WITH wx1@0 wy1@0;

RIy WITH wx1@0 wy1@0;

OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;

在上述语法中，语法1的“ANALYSIS: MODEL = NOCOV;”与语法2的“RIx WITH wx1@0 wy1@0; RIy WITH wx1@0 wy1@0;”的操作是等价的，目的都是将Mplus的默认操作改变。在Mplus中，会默认估计随机截距与第一个时间点个体内变量之间的相关，在上图中就是Rix与wx1、wy1之间的相关，Riy与wx1、wy1之间的相关。而根据研究者的看法，不需要估计这4个相关关系，因此需要语句来改变Mplus这个默认设置。

We are not including covariances between the within-person components at the first occasion and the random intercepts because typically the observations have started at an arbitrary time point in an ongoing process and there is no reason to assume that the within components at the first occasion are correlated to the random intercepts (Mulder & Hamaker, 2021).

希望上述介绍可以帮助到你！也欢迎大家在评论区多多交流分享。

你的关注/点赞 /收藏★/分享，是最大的支持！

本文标签： 语法模型MplusCLPMRI